Difference between revisions of "Comparing investments"

From Bogleheads
Jump to navigation Jump to search
(Updated Google Doc source file URL.)
m (typo, reference update.)
Line 37: Line 37:
  
 
===Fundamental Property #1===
 
===Fundamental Property #1===
The first important property of ''present value'' is that the higher the interest rate (or discount rate<ref>Calculating the ''present value'' is also referred to as ''discounting''. The interest rate is referred to as the ''discount rate'' and ''present value'' is also known as ''discounted value''.</ref>), the lower the present price.<ref>Fabozzi, Frank J., "Fixed Income Mathematics, Analytical & Statistical Techniques", [http://www.amazon.com/Fixed-Income-Mathematics-Frank-Fabozzi/dp/0786311215?tag=bogleheads.org-20 3rd edition], page 22.<br> Note: The graphs on this page are from this text. There are no spreadsheet programs used in this book- the examples are used to verify results from Excel.</ref>
+
The first important property of ''present value'' is that the higher the interest rate (or discount rate<ref>Calculating the ''present value'' is also referred to as ''discounting''. The interest rate is referred to as the ''discount rate'' and ''present value'' is also known as ''discounted value''.</ref>), the lower the present price.<ref>Fabozzi, Frank J., "Fixed Income Mathematics, Analytical & Statistical Techniques", [http://www.amazon.com/Fixed-Income-Mathematics-Frank-Fabozzi/dp/0786311215?tag=bogleheads.org-20 3rd edition], page 22.<br> Note: The graphs on this page are not from this text (derived by the wiki editor). There are no spreadsheet programs used in this book- the examples are used to verify results from Excel.</ref>
  
 
The higher the interest rate, the less that has to be invested today to achieve the same value in the future.   
 
The higher the interest rate, the less that has to be invested today to achieve the same value in the future.   
Line 584: Line 584:
 
*Fabozzi, Frank J., "Fixed Income Mathematics, Analytical & Statistical Techniques", [http://www.amazon.com/Fixed-Income-Mathematics-Frank-Fabozzi/dp/0786311215?tag=bogleheads.org-20 3rd edition]. Also available:  [http://www.amazon.com/Fixed-Income-Mathematics-Analytical-Statistical/dp/007146073X?tag=bogleheads.org-20 4th edition]
 
*Fabozzi, Frank J., "Fixed Income Mathematics, Analytical & Statistical Techniques", [http://www.amazon.com/Fixed-Income-Mathematics-Frank-Fabozzi/dp/0786311215?tag=bogleheads.org-20 3rd edition]. Also available:  [http://www.amazon.com/Fixed-Income-Mathematics-Analytical-Statistical/dp/007146073X?tag=bogleheads.org-20 4th edition]
 
*Files used for this article (from Google): [http://docs.google.com/leaf?id=0B8VSNcUR-B6IOGJkNDYwZWItNGNiZS00ZTcwLWIxOTAtNDM5ZWI5YmVkZjhk BH Wiki - Present Value.zip]
 
*Files used for this article (from Google): [http://docs.google.com/leaf?id=0B8VSNcUR-B6IOGJkNDYwZWItNGNiZS00ZTcwLWIxOTAtNDM5ZWI5YmVkZjhk BH Wiki - Present Value.zip]
**Anyone can download, no account required. Contains MS PowerPoint, MS Excel in both Office 2003 and 2007 formats.
+
**Anyone can download, no account required. Contains MS PowerPoint, MS Excel in Office 2003 compatible format.
 
*[http://en.wikipedia.org/wiki/Net_present_value Net present value], on Wikipedia
 
*[http://en.wikipedia.org/wiki/Net_present_value Net present value], on Wikipedia
 
*[http://en.wikipedia.org/wiki/Internal_rate_of_return Internal rate of return]. on Wikipedia
 
*[http://en.wikipedia.org/wiki/Internal_rate_of_return Internal rate of return]. on Wikipedia

Revision as of 20:24, 17 March 2010

Chart.png It is requested that a diagram or chart be included in this article to improve its quality and clarify the data presented.
Please improve this article if you can, or talk about solutions on the discussion page.

Template:Bogleheads Investing Start-Up Kit Cash flow diagrams in progress. Comments / corrections are welcome. Please post in New in Wiki - Comparing Investments.

This article shows how to compare the past performance of two investments. Solutions are provided to allow the reader to duplicate the results with a spreadsheet.

There are many online financial calculators that do exactly what this article describes. However, the reader is placing full confidence that the math behind the online calculator (1) is accurate and (2) uses assumptions expected by the reader. There should be no surprises, especially when finances are involved. Having your own spreadsheet clearly defines the situation. What-if scenarios are easily done, especially since the data can be manipulated to see trends with a simple chart.

Caveat: Past performance is no guarantee of future performance. Interpretation of results is the responsibility of the reader. If there are any questions, please don't hesitate to ask in the forum for guidance.

Microsoft Excel was used for this article. However, Open Office Calc will work equally well and is a free application that is supported on several operating systems. Open Office financial functions are very similar to Microsoft's functions.[1]

To use this article, copy the formulas from the example tables below and paste into a spreadsheet. The examples are also available for download at the bottom of this page.

Present Value

In order to evaluate a financial investment, prices are referenced as if the money is invested today. The amount of money that must be invested today is called present value. Using the same point in time allows comparison between different financial instruments, e.g. an "apples-to-apples" comparison.

The equation for Present Value can be expressed as[2]:

PV = FV * 1 / (1 + i)N -or- PV = FV * (1 + i)-N

where

PV is the present value (amount of money today)
FV is the future value (amount of money at some point in the future)
i is the interest rate
N is the number of periods

The graph below shows the general idea. The slope of the line depends on the interest rate (i) and the number of payments (N).

Equate Future Prices to the Present
Reference future values to present value.png


Fundamental Property #1

The first important property of present value is that the higher the interest rate (or discount rate[3]), the lower the present price.[4]

The higher the interest rate, the less that has to be invested today to achieve the same value in the future.

Increasing the interest rate lowers the price.
Increases in the interest rate lowers the price.png


Fundamental Property #2

The second important property of present value is that for a given interest rate (or discount rate), the farther into the future the investment will be received, the lower the present value.[5]

Longer term investments have more time for the interest to accumulate, resulting in fewer dollars that need to be invested.

The longer the investment time, the lower the price.
Longer investement time - lower price.png


Cash Flow Diagrams

(in process)--LadyGeek 00:20, 17 March 2010 (UTC)


Financial Functions

Sign Convention

Financial functions use a standard sign convention to indicate the direction of cash flow.[6]

  • A positive sign is used for money that flows into our hand.
  • A negative sign is used for money that flows out of our hand.

Whether a cash flow is an inflow (+) or outflow (-) depends on your perspective. For example, money paid on a loan (outflow) is negative.[7]

Note:

  • One wrong sign will change the computed results and give an incorrect answer.
  • If you consistently change all signs in the problem, you switch roles (for example, switching from being the borrower to being the lender)
  • In all problems, both signs must be used. Sometimes the other sign is in the answer.

Financial variables

There are six financial variables.[8]

  1. PV: The first unequal money in or out of the cash flow diagram is the Present Value.
  2. FV: The last unequal money in or out of the cash flow diagram is the Future Value.
  3. PMT: A fixed amount received in each period is the Payment.
  4. Type: Money received at the “end of the period” is Excel Type = 0. Money received at the “beginning of the period” is Excel Type = 1.
  5. N: Number of periods.
  6. I: Interest rate per period.

N and I must be expressed in the same terms. If N is years, then I must be expressed in years. If N is months, then I must be expressed in months.


How to Compare Investments

  1. Sum the individual cash flows (every payment and any final value) in today's price for each investment.
  2. Compare the prices.

Comparing Interest Rates

Compare the offered price to the present value.
Compare offered price to present value.png

Example 1

An investing opportunity offers to pay $500 at the end of each year for the next 20 years. At the end of 20 years, the value of this investment is zero, it can not be sold.

For example: You loan your friend some money. In 20 years when the debt is repaid, its value is zero.

The purchase price of this opportunity is $5,300.

If the investor wants a 5.5% interest rate, is this a good investment?[9]

Solution:
(insert cash flow diagram here)--LadyGeek 21:56, 15 March 2010 (UTC)

  • I = 5.5 (this is the APY)
  • N = 20 (each period is one year)
  • PMT = 500 (sign is positive because money flows into our hand)
  • FV = 0 (there is no last period unequal amount received)
  • Type = 0 (end of period payments)
  • PV = (solve for this)

With Excel:

Present Value Excel Formula
($5,975.19) =PV(5.5%,20,+500)

The PV of this investment is $5,975.19. The sign is negative because we should pay (money out of our hand) this much today to buy this investment. Forgetting the sign, this investment is worth $5,975.19.

Since we can buy an investment worth $5,975.19 for only $5,300, it is a good investment.

Example 2

An investing opportunity offers to pay $100 per year for the next 5 years and an additional $1,000 at the end of 5 years. The purchase price is $1,243.83.

If the investor wants a 6.25% interest rate, is this a good investment?[10]

Solution:
(insert cash flow diagram here)--LadyGeek 21:56, 15 March 2010 (UTC)

  • I = 6.25 (this is the APY)
  • N = 5 (each period is one year)
  • PMT = 100 (sign is positive because money flows into our hand)
  • FV = 1000 (sign is positive because money flows into our hand)
  • Type = 0 (end of period payments)
  • PV = (solve for this)

With Excel:

Present Value Excel Formula
($1,156.90) =PV(6.25%,5,100,1000,0)

The PV of this investment is $1,156.90. Remember the negative sign only tells us that the money flows out of our hand to buy it, nothing more. Ignore the sign, this investment is worth $1,156.90.

Example 3

Would you like to receive $15,000 today or $18,000 in four years?

The answer depends on the interest rate. If you can find an investment with good interest rate, it will be better to take the $15,000 today. How do you find the interest rate to invest $15,000 today?

Use a starting guess of 4%. The present value of $18,000 received four years from now is $15,386.48. Since the present value is higher than $15,000 (receiving $386.48 more) it is still better to receive $18,000 in four years.[11]

With Excel:

Present Value Excel Formula
$15,386.48 =PV(4%,4,0,-18000)

Now, let Excel remove the guess work and find where it would be more beneficial to receive the $15,000 now.

Use the Goal Seek function (see Excel help for details) to set the value of Cell F13 to zero by adjusting Cell C13.

With Excel (displayed):

Rate PV Purchase Price Difference
4.0% $15,386.48 $15,000.00 $386.48
4.7% $15,000.00 $15,000.00 $0.00

Excel formulas (copy these into your spreadsheet):

  Rate
(Column C)
PV
(Column D)
Purchase Price
(Column E)
Difference
(Column F)
Row 12 0.04 =PV(C12,4,0,-18000) 15000 =D12-E12
Row 13 0.0466 =PV(C13,4,0,-18000) 15000 =D13-E13

If you can get more than 4.7% for your investment now, take the $15,000.

Comparing Interest Rates and Maturity Dates

Compare with different interest rates and maturity dates.
Compare two investments.png

Example 4

Which is better: $140,000 paid over the next 36 months or $160,000 paid over the next 60 months? Clearly $160,000 is better than $140,000 but what is the interest rate on the deferred funds to get the additional $20,000?[12]

Phrased differently, what is the interest rate for the first investment (36 months) to match the 60 month investment ($160,000)?

The interest rate where it would be worthwhile to take the $140,000 in 36 months is 14.90%.

How:

Find the interest rate where the present value of both investments are equal. In other words, make the present value of the two investments in the figure above equal height by adjusting the interest rate (ignore the FV height difference, the graph is easier to read this way). Adjust the interest rate for both investments simultaneously to find where the arrows align.

Let Excel do the work. Use the Goal Seek function (see Excel help for details) to set the value of Cell P11 to zero by adjusting Cell K11.

Displayed values:

Effective
Annual Yield
Nominal
Interest Rate
Monthly
Interest Rate
36 Month Investment 60 Month Investment Difference
15.96% 14.90% 1.24% $112,346.88 $112,346.88 ($0.00)

Cell Formulas:

  Effective
Annual Yield
(Column K)
Nominal
Interest Rate
(Column L)
Monthly
Interest Rate
(Column M)
36 Month Investment
(Column N)
60 Month Investment
(Column O)
Difference
(Column P)
Row 11 0.15957 =NOMINAL(K11,12) =L11/12 =PV(M11,36,-140000/36) =PV(M11,60,-160000/60) =N11-O11

There is an important assumption that exemplifies the need for caution. Nowhere does it say that the interest is an annual rate! This problem is stated in months, and the solution is a rate per month.[12] That's how the PV() equation works. All time periods must be the same. If the reader interpreted this as annual rate, a significant error of 1.06% results.

There are 2 columns of interest here. Effective Annual Yield and Nominal Interest Rate, which are explained below. The Goal Seek function was used to find the annual yield, which flows into the monthly rate.


Compounded Interest Rates

As shown in Example 4, the time period and type of interest (compounded[13] or simple) needs to be clearly defined. Use Excel to convert between an annual yield and the rate for the period of interest.

Caution: There is a difference between interest rate and yield.

Yield

Yield is defined as the return on an investment. It is computed by determining the interest rate that will make the present value of the cash flow from an investment equal to its price. This is shown mathematically as:

p = C1/(1 + y) + C2/(1 + y)2 + C3/(1 + y)3 + ... +CN/(1 + y)N

where

p = Price
Ct = Cash flow in year t
y = Yield (interest rate used to determine the price of the investment)
N = Number of years

The yield calculated above is also called the internal rate of return.[14]

If the equation is confusing, just remember that interest rate is used to determine the yield of an investment. For example, CDs often quote both the periodic interest rate and the effective annual yield. The higher interest rate is the effective annual yield.

Periodic Interest Rate

By definition, the periodic rate is the annual rate divided by the number of periods per year. So multiply the periodic rate by the number of periods per year to get the annual rate.[15] For example, if we have an annual interest rate and want to find the semiannual interest rate, just divide the annual rate by 2.

However, simply multiplying the periodic rate by the number of periods per year introduces an error when compounding. The annual interest rate needs to be converted into an effective annual yield, which results in the following exponential equation:[16]

Effective annual yield = (1 + Periodic Interest rate)m + 1

where

m = Frequency of payments per year

Note: Excel functions RATE and IRR return the periodic rate, while XIRR returns the annualized yield.[15]

Approximating the Interest Rate

More often than not, monthly interest rates are obtained from the effective annual yield by simply dividing by the number of periods. For example, a monthly interest rate is usually taken as the annual rate / 12.

For typical interest rates, simple multiplication is often close enough to the exponential equation. It produces the result with a lot less work if you don't have a calculator that can do exponential and logarithmic functions.

For example, 3% per year is 0.25% per month by division, and 0.246627% per month by the exponential formula- a difference of only 0.0034 percentage points.

Going the other way, 0.25% per month is 3% by multiplication or 3.041596% by exponential formula.

It's possible that the use of simple multiplication in certain contexts (such as monthly vs. annual interest rates) is traditional and dates back to the pre-calculator era.[15]

Consequences of Approximation Errors

Caution is advised when approximating interest rates for large amounts of funds over long periods of time.

For example, a home mortgage is available for an annual interest rate of 12%. However, it's not clearly stated whether the rate is compounded yearly or monthly. The difference is only

0.0511 % per month = 1 % (12% / 12) - 0.949% (NOMINAL(0.12,12)/12)

Compounding over 16 years results in an overpayment by the homeowner of several thousand dollars. See the forum discussion for details. Information was missing to fully define the problem, but it is an example of why the investor needs to understand the implications of approximating interest rates.

Example 5

Show the monthly interest rates for a given effective annual yield. Conversely, show the effective annual yield for a monthly interest rate.

Displayed values:

  Annual Yield
(Column K)
Nominal Monthly Rate   Monthly Rate
(Column N)
Effective Annual Yield
Row 22 10% 0.80%   2.0% 26.82%
Row 23 8% 0.64%   1.5% 19.56%
Row 24 6% 0.49%   1.1% 14.03%
Row 25 4% 0.33%   1.0% 12.68%
Row 26 2% 0.17%   0.5% 6.17%

Cell formulas:

  Annual Yield
(Column K)
Nominal Monthly Rate   Monthly Rate
(Column N)
Effective Annual Yield
Row 22 0.1 =NOMINAL(K22,12)/12   0.02 =EFFECT(N22*12,12)
Row 23 0.08 =NOMINAL(K23,12)/12   0.015 =EFFECT(N23*12,12)
Row 24 0.06 =NOMINAL(K24,12)/12   0.011 =EFFECT(N24*12,12)
Row 25 0.04 =NOMINAL(K25,12)/12   0.01 =EFFECT(N25*12,12)
Row 26 0.02 =NOMINAL(K26,12)/12   0.005 =EFFECT(N26*12,12)


Unequal Payments

The present value formula can only be used if all payments are the same amount. Suppose you have a series of payments that vary every period? The theory is the same- sum the present value of the individual cash flows (payments). The only difference is that you need to use a present value function for each payment.

Example 6

Suppose you have the opportunity to purchase an investment which promises to make the following payments every quarter (3 months, see table below). If a 12% interest rate is desired, what is the most that you should pay for it?

You should pay at most $8,212.79.[17]

How:

First, note that neither the type of interest nor the period of time is stated. For this problem, it's 12 % per year, but the quarterly interest is defined as 3% = 12% / 4. This is simple interest, no compounding is used.

Since the payments vary every 3 month period, the present value of each payment is calculated. Then, the payments are summed to get the total present value. Excel already has a function that will do the individual calculations for you, called Net Present Value. Note that the answers match (Sum of Column F with Net Present Value in Cell G20).

Displayed values:

  Interest Rate
(Quarterly) (Column C)
3 Month Period
(Column D)
Payment
(Column E)
Present Value
(Column F)
Net Present Value
(Column G)
Row 20 0.03 1 1000 $970.87 $8,212.79
Row 21 0.03 2 1200 $1,131.12  
Row 22 0.03 3 1500 $1,372.71  
Row 23 0.03 4 1700 $1,510.43  
Row 24 0.03 5 1800 $1,552.70  
Row 25 0.03 6 2000 $1,674.97  
      Sum of Present Value: $8,212.79  

Cell formulas:

  Interest Rate (Quarterly)
(Column C)
3 Month Period
(Column D)
Payment
(Column E)
Present Value
(Column F)
Net Present Value
(Column G)
Row 20 0.03 1 1000 =PV(C20,D20,0,-E20) =NPV(C20,E20:E25)
Row 21 0.03 2 1200 =PV(C21,D21,0,-E21)  
Row 22 0.03 3 1500 =PV(C22,D22,0,-E22)  
Row 23 0.03 4 1700 =PV(C23,D23,0,-E23)  
Row 24 0.03 5 1800 =PV(C24,D24,0,-E24)  
Row 25 0.03 6 2000 =PV(C25,D25,0,-E25)  
      Sum of Present Value: =SUM(F20:F25)  

Both Present Value and Net Present Value assume that the interest rate is defined. Suppose that you only have the payments. How do you calculate the interest?

Not a problem. Just use the Internal Rate of Return function, IRR, to find the yield (internal rate of return). Finding the solution is somewhat more complicated and best left to Excel. Refer to Microsoft's help for information on the IRR function. Pay special attention to setting up the problem. The sum of the income and payments must be zero for the function to work.


References

  1. Open Office Calc Financial functions. For example PV(rate; numperiods; payment; futurevalue; type) is identical.
  2. Understanding The Time Value Of Money
  3. Calculating the present value is also referred to as discounting. The interest rate is referred to as the discount rate and present value is also known as discounted value.
  4. Fabozzi, Frank J., "Fixed Income Mathematics, Analytical & Statistical Techniques", 3rd edition, page 22.
    Note: The graphs on this page are not from this text (derived by the wiki editor). There are no spreadsheet programs used in this book- the examples are used to verify results from Excel.
  5. Fabozzi, page 22.
  6. From forum member, via PM.
  7. Excel help for PV().
  8. From forum member, via PM.
  9. Fabozzi, page 25. Comments and solution from forum member.
  10. Fabozzi, page 24. Solution from forum member.
  11. From Understanding The Time Value Of Money, but extended to show the break-even point.
  12. 12.0 12.1 $140,000 over 3 years or $160,000 over 5 years
  13. Compounding, on Investopedia
  14. Fabozzi, page 34.
  15. 15.0 15.1 15.2 New in Wiki - Comparing Investments, forum discussion
  16. Fabozzi, page 41.
  17. Fabozzi, page 28.


External Links

Excel Functions

Microsoft's help files are well documented with working examples for each function. If using Open Office, Microsoft descriptions may be more informative. Enable browser cookies to view.

  • PV, Present Value.
  • NPV, Net Present Value
  • IRR, Internal Rate of Return
  • XIRR, Internal Rate of return for cash flows that are not periodic
  • Effect, Convert to Effective annual yield from the periodic rate
  • Nominal, Convert to Periodic interest rate from the effective annual yield
  • RATE, Interest rate per period of an annuity

Forum Discussions